Adressenbestand

Originele schrijvers mogen hier hun eigen code Public Domain maken.

Adressenbestand

Berichtdoor Luit-pieter » zo sep 16, 2007 11:29 pm

Dit is een prog. die ik gebruikte om diverse dingen uit te proberen
dus als er iemand gebruik van kan maken, des te beter.

Luit

Code: Selecteer alles
'Form created with the help of Freeform 3 v03-27-03
'Generated on Dec 27, 2006 at 00:47:20

NOMAINWIN
Base = 1
Dum = 2
GLOBAL Lijst$, Naam$, Adres$, Woonpl$, R$, Postc$, Tel$, Best$, Rec, Inv, Wis, Ad$

DIM Lijst$(1), info$(1, 1), Adr$(1), Label$(1, 1)

path$ = DefaultDir$
Pad$ = RIGHT$(path$, LEN(path$) - 2)
filename$ = Pad$ + "\Tt"
Maken = BestaatDir(DefaultDir$, filename$)
IF Maken = 0 THEN
  Result = mkdir( "Tt")
END IF
Ad$ = "ADRES"
IF Bestaat(DefaultDir$, "*.GEG") <> 0 THEN
  CALL OpenDatabase
ELSE
  OPEN Ad$ + ".GEG" FOR OUTPUT AS #Dum
  CLOSE #Dum
  CALL OpenDatabase
END IF

[setup.main.Window]
'-----Begin code for #main
WindowWidth = 550
WindowHeight = 410
UpperLeftX = 300
UpperLeftY = 300
'-----Begin menu code
menu #main, "Bestand", "Invoer", [Invoer], "Verander", [Verander], "Wissen", [Wis],_
            "Open", [Obest], "Maken", [Maak]
menu #main, "Lijst", "Scherm", [Lijst], "Papier", [Papier]
'-----End menu code
STATICTEXT #main, "ADRESSEN", 225, 150, 100, 25
OPEN "Adressen" FOR GRAPHICS_NSB AS #main
PRINT #main, "trapclose [quit.main]"
WAIT

[quit.main]
CLOSE #main
CLOSE #Base
END
WAIT

[Maak]
WindowWidth = 320
WindowHeight = 100
UpperLeftX= 10
UpperLeftY= 10
STATICTEXT #MB, "Naam bestand:", 10, 20, 200, 20
TEXTBOX #MB.Tx, 10, 40, 150, 20
BUTTON #MB.Bt1, "Bewaar", [BestMak], UL, 180, 40, 50, 20
BUTTON #MB.Bt2, "STOP", [MBquit], UL, 240, 40, 50, 20
OPEN "Maak bestand" FOR DIALOG_MODAL AS #MB
PRINT #MB, "trapclose [MBquit]"
WAIT

[BestMak]
PRINT #MB.Tx, "!contents? MBes$";
MBes$ = UPPER$(MBes$)
IF Bestaat(DefaultDir$, LEFT$(MBes$,3) + "*.GEG") <> 0 THEN
  NOTICE "Eerste drie letters van naam zijn gelijk aan bestaande naam"
  GOTO [UitBest]
END IF
IF MBes$ <> "" THEN
  CLOSE #Base
  Ad$ = MBes$
  OPEN Ad$ + ".GEG" FOR RANDOM AS #Base LEN = 103
  CLOSE #Base
  CALL OpenDatabase
END IF
CLOSE #MB
[UitBest]
WAIT

[MBquit]
CLOSE #MB
WAIT

[Obest]
files DefaultDir$, "\*.GEG", info$()
Y = VAL(info$(0, 0))
IF Y > 1 THEN
  REDIM Adr$(Y)
  W = 0
  FOR i = 1 TO Y
    W = W + 1
    x = INSTR(info$(i, 0), ".")
    Adr$(W) = LEFT$(info$(i, 0), x - 1)
  NEXT i
  WindowWidth = 120
  WindowHeight = 150
  UpperLeftX= 10
  UpperLeftY= 10
  LISTBOX #Adre.Lb, Adr$(), [OpAdr], 10, 10, 90, 50
  BUTTON #Adre.Bt, "STOP", [Adquit], UL, 30, 80, 50, 20
  OPEN "Adres" FOR DIALOG_MODAL AS #Adre
  PRINT #Adre, "trapclose [Adquit]"
ELSE
  NOTICE "Geen andere Adres bestanden"
END IF
WAIT

[OpAdr]
PRINT #Adre.Lb, "selectionindex? index"
Ad$ = Adr$(index)
CLOSE #Base
CALL OpenDatabase
CLOSE #Adre
WAIT

[Adquit]
CLOSE #Adre
WAIT

[Lijst]
WindowWidth = 700
WindowHeight = 410
UpperLeftX= 10
UpperLeftY= 10
LISTBOX #List.Lb, Lijst$(), [Zien], 10, 10, 680, 300
BUTTON #List.b1, "STOP", [Liquit], UL, 20, 340, 75, 25
BUTTON #List.b2, "Tekst", [Tekst], UL, 150, 340, 75, 25
BUTTON #List.b3, "Zoek", [Zoek], UL, 250, 340, 75, 25
TEXTBOX #List.Txz, 330, 340, 210, 25
OPEN "Lijst" FOR DIALOG_MODAL AS #List
PRINT #List, "trapclose [Liquit]"
PRINT #List, "font COURIER_NEW 10"
PRINT #List.Lb, "setfocus"
WAIT

[Zoek]
PRINT #List.Txz, "!contents? var$";
D = 0
FOR i = 1 TO Rec
  GET #Base, i
  IF INSTR(UPPER$(Lijst$(i)), UPPER$(var$)) <> 0 THEN
    CONFIRM Lijst$(i); Antw$
    IF Antw$ = "yes" THEN
      D = 1
      EXIT FOR
    END IF
  END IF
NEXT i
IF D = 1 THEN
  PRINT #List.Lb, "selectindex "; i
ELSE
  NOTICE "Niet gevonden"
END IF
WAIT

[Liquit]
CLOSE #List
WAIT

[Zien]
WindowWidth = 550
WindowHeight = 310
UpperLeftX= 10
UpperLeftY= 10
PRINT #List.Lb, "selectionindex? index"
GET #Base, index
STATICTEXT #Geg, "Naam       :"; Naam$, 10, 20, 500, 25
STATICTEXT #Geg, "Adres      :"; Adres$, 10, 50, 500, 25
STATICTEXT #Geg, "Woonplaats :"; Woonpl$, 10, 80, 500, 25
STATICTEXT #Geg, "Postcode   :"; Postc$, 10, 110, 500, 25
STATICTEXT #Geg, "Telefoon   :"; Tel$, 10, 140, 500, 25
BUTTON #Geg.b1, "STOP", [Gequit], UL, 20, 210, 75, 25
OPEN "Gegevens" FOR DIALOG_MODAL AS #Geg
PRINT #Geg, "trapclose [Gequit]"
PRINT #Geg, "font COURIER_NEW 10"
WAIT

[Gequit]
CLOSE #Geg
WAIT

[Tekst]
PRINT #List.Lb, "selectionindex? index"
IF index = 0 THEN
  NOTICE "Geen Naam geselecteerd"
  GOTO [UitTekst]
END IF
GET #Base, index
Be$ = LEFT$(Ad$, 3)
Best$ = DefaultDir$ + "\Tt\" + Be$ + STR$(index) + ".OMS"
IF Bestaat(DefaultDir$ + "\Tt\", Be$ + STR$(index) + ".OMS") = 0 THEN
  A$ = "Bestand bestaat niet" + CHR$(13)
  A$ = A$ + "Bestand maken"
  CONFIRM A$; Antw$
  IF Antw$ <> "yes" THEN
    GOTO [UitTekst]
  END IF
  OPEN Best$ FOR OUTPUT AS #DT
  CLOSE #DT
END IF
CALL DoeWerk
PRINT #We, "!trapclose [Wequit]"
[UitTekst]
WAIT

[Wequit]
PRINT #We, "!modified? answer$" ;
IF answer$ = "true" THEN
  CONFIRM "Veranderingen opslaan"; Antw$
  IF Antw$ = "yes" THEN
    PRINT #We, "!contents? string$";
    OPEN Best$ FOR OUTPUT AS #DT
    PRINT #DT, string$
    CLOSE #DT
  END IF
END IF
CLOSE #We
WAIT

SUB DoeWerk
WindowWidth = 600
WindowHeight = 300
UpperLeftY = 350
UpperLeftX = 320
OPEN Naam$ FOR TEXT AS #We
OPEN Best$ FOR INPUT AS #DT
PRINT #We, "!contents #DT";
CLOSE #DT
END SUB

[Papier]
IF Rec < 1 THEN
  NOTICE "Geen adressen aanwezig"
  GOTO [Uitklant]
END IF
WindowWidth = 125
WindowHeight = 100
UpperLeftY = 200
UpperLeftX = 100
BUTTON #Pk.B1, "Alle klanten", [Aklant], UL, 5, 5, 100, 20
BUTTON #Pk.B2, "Van/Tot", [Vklant], UL, 5, 25, 100, 20
BUTTON #Pk.B3, "STOP", [Pkstop], UL, 5, 45, 100, 20
OPEN "Print" FOR DIALOG_MODAL AS #Pk
PRINT #Pk, "trapclose [Pkstop]"
[Uitklant]
WAIT

[Aklant]
CLOSE #Pk
Eerste = 1
Laatste = Rec
GOTO [DoeKlant]
WAIT

[Vklant]
CLOSE #Pk
WindowWidth = 250
WindowHeight = 200
UpperLeftY = 200
UpperLeftX = 100
STATICTEXT #Vpk, "VAN KLANTNUMMER TOT", 25, 10, 200, 25
STATICTEXT #Vpk, "VAN", 25, 40, 50, 25
STATICTEXT #Vpk, "TOT", 95, 40, 50, 25
TEXTBOX #Vpk.T1, 25, 70, 50, 25
TEXTBOX #Vpk.T2, 95, 70, 50, 25
BUTTON #Vpk.ok, "OK", [VpkOk], UL, 25,110, 70, 25
BUTTON #Vpk.St, "STOP", [VpkStop], UL, 120, 110, 70, 25
OPEN "Print klant" FOR DIALOG_MODAL AS #Vpk
PRINT #Vpk, "font COURIER_NEW 11"
PRINT #Vpk.T1, "!setfocus";
PRINT #Vpk, "trapclose [VpkStop]"
WAIT

[VpkOk]
PRINT #Vpk.T1, "!contents? Doe1$";
PRINT #Vpk.T2, "!contents? Doe2$";
CLOSE #Vpk
Eerste = VAL(Doe1$)
Laatste = VAL(Doe2$)
IF Eerste < 1 THEN
  Eerste = 1
END IF
IF Laatste > Rec THEN
  C$ = "Hoogste Klant nummer is " + STR$(Rec) + CHR$(13) + " Nummer aanpassen"
  CONFIRM C$; Antw$
  IF Antw$ = "yes" THEN
    Laatste = Rec
  ELSE
    Eerste = 0
    Laatste = 0
  END IF
END IF
IF Eerste > Laatste THEN
  NOTICE "Klant nummers niet juist"
  Eerste = 0
  Laatste = 0
END IF
IF Eerste > 0 AND Laatste > Eerste THEN
  GOTO [DoeKlant]
END IF
WAIT

[VpkStop]
CLOSE #Vpk
WAIT

[DoeKlant]
Goed = 0
Dummy = Laatste
REDIM Voor$(Dummy, 3)
Y = Eerste - 1
FOR i = Eerste TO Dummy
  GET #Base, i
  IF Stat$ <> "*" THEN
    Y = Y + 1
    I$ = TRIM$(Titel$) + TRIM$(Initial$) + TRIM$(Aanhef$) + " " + Naam$
    IF LEN(I$) > 24 THEN
      I$ = LEFT$(I$, 24)
    END IF
    Voor$(Y, 1) = I$
    IF LEN(Adres$) > 24 THEN
      Adres$ = LEFT$(Adres$, 24)
    END IF
    Voor$(Y, 2) = Adres$
    PW$ = Postc$ + " " + Woonpl$
    IF LEN(PW$) > 24 THEN
      PW$ = LEFT$(PW$, 24)
    END IF
    Voor$(Y, 3) = PW$
  END IF
NEXT i
IF Y < Laatste THEN
  Laatste = Y
END IF
DO
  IF Laatste / 3 <> INT(Laatste / 3) THEN
    Laatste = Laatste + 1
  ELSE
    Goed = 1
  END IF
LOOP UNTIL Goed = 1
REDIM Label$(Laatste, 3)
FOR i = Eerste TO Y
  FOR x = 1 TO 3
    Label$(i, x) = Voor$(i, x)
  NEXT x
NEXT i
IF Y < Laatste THEN
  DO
    Y = Y + 1
    Label$(Y, 1) = " "
    Label$(Y, 2) = " "
    Label$(Y, 3) = " "
  LOOP UNTIL Y = Laatste
END IF
PrinterFont$ = "courier_new 10 bold"
FOR i = Eerste TO Laatste STEP 3
  FOR x = 1 TO 3
    LPRINT Label$(i, x);TAB(30);Label$(i + 1, x);TAB(58);Label$(i + 2, x)
  NEXT x
  LPRINT
  LPRINT
  LPRINT
  LPRINT
  LPRINT
  LPRINT
  LPRINT
  LPRINT
NEXT i
DUMP
WAIT

[Pkstop]
CLOSE #Pk
WAIT

[Invoer]
FOR i = 1 TO Rec
  GET #Base, i
  IF Stat$ = "*" THEN
    Inv = i
    EXIT FOR
  END IF
NEXT i
IF i >= Rec THEN
  Inv = Rec + 1
END IF
WindowWidth = 500
WindowHeight = 300
UpperLeftX= 10
UpperLeftY= 10
TEXTBOX #Nam.Txn, 150, 10, 210, 25
TEXTBOX #Nam.Txa, 150, 40, 210, 25
TEXTBOX #Nam.Txw, 150, 70, 170, 25
TEXTBOX #Nam.Txp, 150, 100, 60, 25
TEXTBOX #Nam.Txt, 150, 130, 210, 25
STATICTEXT #Nam, "Naam       :", 10, 20, 100, 25
STATICTEXT #Nam, "Adres      :", 10, 50, 100, 25
STATICTEXT #Nam, "Woonplaats :", 10, 80, 100, 25
STATICTEXT #Nam, "Postcode   :", 10, 110, 100, 25
STATICTEXT #Nam, "Telefoon   :", 10, 140, 100, 25
BUTTON #Nam.b1, "STOP", [Naquit], UL, 20, 210, 75, 25
BUTTON #Nam.b2, "Bewaar", [GegBew], UL, 150, 210, 75, 25
OPEN "Gegevens invoer nummer ";Inv, FOR DIALOG_MODAL AS #Nam
Ntext = hwnd(#Nam.Txn)
calldll #user32, "SendMessageA", Ntext AS LONG, _EM_LIMITTEXT AS LONG, 25 AS LONG,_
0 AS LONG, ret AS LONG
Atext = hwnd(#Nam.Txa)
calldll #user32, "SendMessageA", Atext AS LONG, _EM_LIMITTEXT AS LONG, 25 AS LONG,_
0 AS LONG, ret AS LONG
Wtext = hwnd(#Nam.Txw)
calldll #user32, "SendMessageA", Wtext AS LONG, _EM_LIMITTEXT AS LONG, 20 AS LONG,_
0 AS LONG, ret AS LONG
Ptext = hwnd(#Nam.Txp)
calldll #user32, "SendMessageA", Ptext AS LONG, _EM_LIMITTEXT AS LONG, 7 AS LONG,_
0 AS LONG, ret AS LONG
Ttext = hwnd(#Nam.Txt)
calldll #user32, "SendMessageA", Ttext AS LONG, _EM_LIMITTEXT AS LONG, 25 AS LONG,_
0 AS LONG, ret AS LONG
PRINT #Nam.Txn, "!setfocus"
PRINT #Nam, "trapclose [Naquit]"
PRINT #Nam, "font COURIER_NEW 10"
WAIT

[GegBew]
PRINT #Nam.Txn, "!contents? Naam$";
PRINT #Nam.Txa, "!contents? Adres$";
PRINT #Nam.Txw, "!contents? Woonpl$";
PRINT #Nam.Txp, "!contents? Postc$";
PRINT #Nam.Txt, "!contents? Tel$";
CONFIRM "Gegevens opslaan"; Antw$
IF Antw$ = "yes" THEN
  Stat$ = ""
  PUT #Base, Inv
  CLOSE #Nam
END IF
CLOSE #Base
CALL OpenDatabase
WAIT

[Naquit]
CLOSE #Nam
WAIT

[Verander]
WindowWidth = 700
WindowHeight = 410
UpperLeftX= 10
UpperLeftY= 10
BUTTON #Ver.b1, "STOP", [Vequit], UL, 20, 340 , 75, 25
BUTTON #Ver.b3, "Zoek", [VZoek], UL, 250, 340 , 75, 25
TEXTBOX #Ver.Txz, 330, 340, 210, 25
LISTBOX #Ver.Lb, Lijst$(), [VerDoe], 10, 10, 680, 300
OPEN "Lijst" FOR DIALOG_MODAL AS #Ver
PRINT #Ver, "trapclose [Vequit]"
PRINT #Ver, "font COURIER_NEW 10"
PRINT #Ver.Lb, "setfocus"
WAIT

[VerDoe]
PRINT #Ver.Lb, "selectionindex? index"
Inv = index
GET #Base, index
WindowWidth = 500
WindowHeight = 300
UpperLeftX= 10
UpperLeftY= 10
TEXTBOX #VerNam.Txn, 150, 10, 210, 25
TEXTBOX #VerNam.Txa, 150, 40, 210, 25
TEXTBOX #VerNam.Txw, 150, 70, 170, 25
TEXTBOX #VerNam.Txp, 150, 100, 60, 25
TEXTBOX #VerNam.Txt, 150, 130, 210, 25
STATICTEXT #VerNam, "Naam       :", 10, 20, 100, 25
STATICTEXT #VerNam, "Adres      :", 10, 50, 100, 25
STATICTEXT #VerNam, "Woonplaats :", 10, 80, 100, 25
STATICTEXT #VerNam, "Postcode   :", 10, 110, 100, 25
STATICTEXT #VerNam, "Telefoon   :", 10, 140, 100, 25
BUTTON #VerNam.b1, "STOP", [VNquit], UL, 20, 210, 75, 25
BUTTON #VerNam.b2, "Bewaar", [VerBew], UL, 150, 210, 75, 25
OPEN "Gegevens veranderen nummer ";Inv, FOR DIALOG_MODAL AS #VerNam
PRINT #VerNam.Txn, Naam$
PRINT #VerNam.Txa, Adres$
PRINT #VerNam.Txw, Woonpl$
PRINT #VerNam.Txp, Postc$
PRINT #VerNam.Txt, Tel$
PRINT #VerNam.Txn, "!setfocus"
PRINT #VerNam, "trapclose [VNquit]"
PRINT #VerNam, "font COURIER_NEW 10"
WAIT
WAIT

[VerBew]
PRINT #VerNam.Txn, "!contents? Naam$";
PRINT #VerNam.Txa, "!contents? Adres$";
PRINT #VerNam.Txw, "!contents? Woonpl$";
PRINT #VerNam.Txp, "!contents? Postc$";
PRINT #VerNam.Txt, "!contents? Tel$";
PUT #Base, Inv
CLOSE #VerNam
WAIT

[VZoek]
PRINT #Ver.Txz, "!contents? var$";
FOR i = 1 TO Rec
  IF INSTR(UPPER$(Lijst$(i)), UPPER$(var$)) <> 0 THEN
    A$ = "Deze gegevens WISSEN" + CHR$(13)
    A$ = A$ + CHR$(13)
    A$ = A$ + Lijst$(i)
    CONFIRM A$; Antw$
    IF Antw$ = "yes" THEN
      Veran = VAL(Lijst$(i))
      PRINT #Ver.Lb, "selectindex "; Veran
      EXIT FOR
    END IF
  END IF
NEXT i
WAIT

[VNquit]
CLOSE #VerNam
WAIT

[Vequit]
CLOSE #Ver
WAIT

[Wis]
WindowWidth = 700
WindowHeight = 410
UpperLeftX= 10
UpperLeftY= 10
BUTTON #Sel.b1, "STOP", [Sequit], UL, 20, 340 , 75, 25
BUTTON #Sel.b3, "Zoek", [VZoek], UL, 250, 340 , 75, 25
TEXTBOX #Sel.Txz, 330, 340, 210, 25
LISTBOX #Sel.Lb, Lijst$(), [Swis], 10, 10, 680, 300
OPEN "Lijst" FOR DIALOG_MODAL AS #Sel
PRINT #Sel, "trapclose [Sequit]"
PRINT #Sel, "font COURIER_NEW 10"
PRINT #Sel.Lb, "setfocus"
WAIT

[Sequit]
CLOSE #Sel
WAIT

[Swis]
IF Wis = 0 THEN
  PRINT #Sel.Lb, "selectionindex? index"
  GET #Base, index
  IF Stat$ = "*" THEN
    B$ = "Herstel"
  ELSE
    B$ = "Wissen"
  END IF
  i = index
  Wis = index
  A$ = B$ + CHR$(13)
  A$ = A$ + CHR$(13)
  A$ = A$ + Lijst$(i)
  CONFIRM A$; Antw$
  IF Antw$ <> "yes" THEN
    GOTO [UitWis]
  END IF
END IF
GET #Base, Wis
IF Stat$ = "*" THEN
  Stat$ = " "
ELSE
  Stat$ = "*"
END IF
PUT #Base, Wis
CLOSE #Base
CALL OpenDatabase
Wis = 0
PRINT #Sel.Lb, "RELOAD"
[UitWis]
WAIT

[SZoek]
PRINT #Sel.Txz, "!contents? var$";
FOR i = 1 TO Rec
  IF INSTR(UPPER$(Lijst$(i)), UPPER$(var$)) <> 0 THEN
    A$ = "Deze gegevens WISSEN" + CHR$(13)
    A$ = A$ + CHR$(13)
    A$ = A$ + Lijst$(i)
    CONFIRM A$; Antw$
    IF Antw$ = "yes" THEN
      Wis = VAL(Lijst$(i))
      PRINT #Sel.Lb, "selectindex "; Wis
      EXIT FOR
    END IF
  END IF
NEXT i
WAIT

SUB OpenDatabase
OPEN Ad$ + ".GEG" FOR RANDOM AS #Base LEN = 103
FIELD #Base, 1 AS Stat$, 25 AS Naam$, 25 AS Adres$, 20 AS Woonpl$, 7 AS Postc$,_
             25 AS Tel$
Rec = LOF(#Base) / 103
REDIM Lijst$(Rec)
FOR i = 1 TO Rec
  GET #Base, i
  R$ = STR$(i)
  IF i < 10 THEN
    R$ = "   " + R$
  END IF
  IF i < 100 AND i > 9 THEN
    R$ = "  " + R$
  END IF
  IF i > 99 THEN
    R$ = " " + R$
  END IF
  IF Stat$ = "*" THEN
    Adres$ = "GEWIST" + SPACE$(64)
    Woonpl$ = ""
  END IF
  Lijst$(i) = makeEntry$(y)
NEXT i
END SUB

FUNCTION makeEntry$(y)
  makeEntry$ = R$;SPACE$(1);Naam$;Space$(1);Adres$;Space$(1);Woonpl$
END FUNCTION

FUNCTION Bestaat(path$, filename$)
  files path$, filename$, info$(
  Bestaat = val(info$(0, 0))
END FUNCTION

FUNCTION BestaatDir(path$, filename$)
  files path$, filename$, info$(
  BestaatDir = 0
  BestAan = VAL(info$(0, 0))
  DirAan = VAL(info$(0, 1))
  FOR i = BestAan TO BestAan + DirAan
    IF TRIM$(filename$) = TRIM$(info$(i, 0)) THEN
      BestaatDir = 1
    END IF
  NEXT i
END FUNCTION

Function GetWindowLong(hW, type)
  CallDLL #user32, "GetWindowLongA", hW As Long, type As Long,GetWindowLong As Long
End Function

Function SetWindowLong(hW,index,newVal)
  CallDLL #user32, "SetWindowLongA", hW As Long,index As Long, newVal As Long,SetWindowLong As Long
End Function


Edit : door Gordon
[ code] en [ /code] geplaatst voor de leesbaarheid.
Luit-pieter
 
Berichten: 3
Geregistreerd: wo dec 13, 2006 10:26 pm
Woonplaats: Rijsenhout

Berichtdoor Gordon » ma sep 17, 2007 12:57 pm

Hallo Pieter,

Knap werk.
Ik plaatste je listing in een aparte map (directory) om
te voorkomen dat de bestanden over mijn hele schijf zouden gaan
zwerven.

Gordon.
Avatar gebruiker
Gordon
Site Admin
 
Berichten: 684
Geregistreerd: zo mei 22, 2005 12:50 am


Keer terug naar Public Domain stukjes

Wie is er online

Gebruikers op dit forum: Geen geregistreerde gebruikers. en 1 gast

cron